mirror of
https://github.com/oven-sh/bun
synced 2026-02-15 05:12:29 +00:00
df61e88dc0
### What does this PR do? The `then` function in `transpiler.transform` can cause GC, which means it can cause the `Transpiler` to become freed, which means that if that same transpiler is in use by another run on the other thread, it could have pointers to invalid memory. Also, `ESMCondition` has unnecesasry memory allocations and there is a very tiny memory leak in optionsFromLoaders ### How did you verify your code works? Existing tests --------- Co-authored-by: autofix-ci[bot] <114827586+autofix-ci[bot]@users.noreply.github.com>
104 lines
2.4 KiB
CMake
104 lines
2.4 KiB
CMake
register_repository(
|
||
NAME
|
||
mimalloc
|
||
REPOSITORY
|
||
oven-sh/mimalloc
|
||
COMMIT
|
||
1cef3e8f4167733818f1883b2f3a9dd4754224cf
|
||
)
|
||
|
||
set(MIMALLOC_CMAKE_ARGS
|
||
-DMI_BUILD_STATIC=ON
|
||
-DMI_BUILD_OBJECT=ON
|
||
-DMI_BUILD_SHARED=OFF
|
||
-DMI_BUILD_TESTS=OFF
|
||
-DMI_USE_CXX=ON
|
||
-DMI_SKIP_COLLECT_ON_EXIT=ON
|
||
|
||
# ```
|
||
# ❯ mimalloc_allow_large_os_pages=0 BUN_PORT=3004 mem bun http-hello.js
|
||
# Started development server: http://localhost:3004
|
||
#
|
||
# Peak memory usage: 52 MB
|
||
#
|
||
# ❯ mimalloc_allow_large_os_pages=1 BUN_PORT=3004 mem bun http-hello.js
|
||
# Started development server: http://localhost:3004
|
||
#
|
||
# Peak memory usage: 74 MB
|
||
# ```
|
||
#
|
||
# ```
|
||
# ❯ mimalloc_allow_large_os_pages=1 mem bun --eval 1
|
||
#
|
||
# Peak memory usage: 52 MB
|
||
#
|
||
# ❯ mimalloc_allow_large_os_pages=0 mem bun --eval 1
|
||
#
|
||
# Peak memory usage: 30 MB
|
||
# ```
|
||
-DMI_NO_THP=1
|
||
)
|
||
|
||
if(ENABLE_ASAN)
|
||
list(APPEND MIMALLOC_CMAKE_ARGS -DMI_TRACK_ASAN=ON)
|
||
list(APPEND MIMALLOC_CMAKE_ARGS -DMI_OVERRIDE=OFF)
|
||
list(APPEND MIMALLOC_CMAKE_ARGS -DMI_OSX_ZONE=OFF)
|
||
list(APPEND MIMALLOC_CMAKE_ARGS -DMI_OSX_INTERPOSE=OFF)
|
||
list(APPEND MIMALLOC_CMAKE_ARGS -DMI_DEBUG_UBSAN=ON)
|
||
elseif(APPLE OR LINUX)
|
||
# Enable static override when ASAN is not enabled
|
||
list(APPEND MIMALLOC_CMAKE_ARGS -DMI_OVERRIDE=ON)
|
||
if(APPLE)
|
||
list(APPEND MIMALLOC_CMAKE_ARGS -DMI_OSX_ZONE=ON)
|
||
list(APPEND MIMALLOC_CMAKE_ARGS -DMI_OSX_INTERPOSE=ON)
|
||
else()
|
||
list(APPEND MIMALLOC_CMAKE_ARGS -DMI_OSX_ZONE=OFF)
|
||
list(APPEND MIMALLOC_CMAKE_ARGS -DMI_OSX_INTERPOSE=OFF)
|
||
endif()
|
||
endif()
|
||
|
||
if(DEBUG)
|
||
list(APPEND MIMALLOC_CMAKE_ARGS -DMI_DEBUG_FULL=ON)
|
||
endif()
|
||
|
||
if(ENABLE_VALGRIND)
|
||
list(APPEND MIMALLOC_CMAKE_ARGS -DMI_VALGRIND=ON)
|
||
endif()
|
||
|
||
# Enable SIMD optimizations when not building for baseline (older CPUs)
|
||
if(NOT ENABLE_BASELINE)
|
||
list(APPEND MIMALLOC_CMAKE_ARGS -DMI_OPT_ARCH=ON)
|
||
list(APPEND MIMALLOC_CMAKE_ARGS -DMI_OPT_SIMD=ON)
|
||
endif()
|
||
|
||
if(DEBUG)
|
||
if (ENABLE_ASAN)
|
||
set(MIMALLOC_LIBRARY mimalloc-asan-debug)
|
||
else()
|
||
set(MIMALLOC_LIBRARY mimalloc-debug)
|
||
endif()
|
||
else()
|
||
set(MIMALLOC_LIBRARY mimalloc)
|
||
endif()
|
||
|
||
# Workaround for linker issue on macOS and Linux x64
|
||
# https://github.com/microsoft/mimalloc/issues/512
|
||
if(APPLE OR (LINUX AND NOT DEBUG))
|
||
set(MIMALLOC_LIBRARY CMakeFiles/mimalloc-obj.dir/src/static.c.o)
|
||
endif()
|
||
|
||
|
||
register_cmake_command(
|
||
TARGET
|
||
mimalloc
|
||
TARGETS
|
||
mimalloc-static
|
||
mimalloc-obj
|
||
ARGS
|
||
${MIMALLOC_CMAKE_ARGS}
|
||
LIBRARIES
|
||
${MIMALLOC_LIBRARY}
|
||
INCLUDES
|
||
include
|
||
)
|