era b:*.lst
era b:*.lin
era b:*.sym
era b:*.bak
isdd
plm80 :f1:gensys.plm pagewidth(80) debug
link :f1:gensys.obj,:f1:x0100,plm80.lib to :f1:gensys.mod
locate :f1:gensys.mod code(0100H) stacksize(100)
era b:gensys.mod
cpm
objcpm b:gensys
pip lst:=b:gensys.lst
pip lst:=b:gensys.sym[pt8]
pip lst:=b:gensys.lin[pt8]
pip lst:=nul:[p]
era b:*.lst
era b:*.sym
era b:*.lin
isdd
plm80 :f1:mpmldr.plm pagewidth(80) debug
asm80 :f1:ldmonx.asm pagewidth(80) debug
link :f1:mpmldr.obj,:f1:ldmonx.obj,plm80.lib to :f1:mpmldr.mod
locate :f1:mpmldr.mod stacksize(48) code(0100h)
objhex :f1:mpmldr to :f1:impmldr.hex
cpm
pip lst:=b:mpmldr.lst
pip lst:=b:ldmonx.lst
pip lst:=nul:[p]
objcpm b:mpmldr
pip lst:=b:mpmldr.sym[pt8]
pip lst:=b:mpmldr.lin[pt8]
pip lst:=nul:[p]
era b:*.lst
era b:*.sym
era b:*.lin
mac b:ldrbdos $$+s
pip lst:=b:ldrbdos.prn[lt8]
era b:ldrbdos.prn
mac b:ldrbios $$+s
pip lst:=b:ldrbios.prn[lt8]
era b:ldrbios.prn
pip b:mpmldr.hex=b:impmldr.hex[I],b:ldrbdos.hex[I],b:ldrbios.hex[H]
load b:mpmldr
era b:mpmldr.hex
