era b:*.lst
era b:*.lin
era b:*.sym
era b:*.bak
isdd
plm80 :f1:stat.plm pagewidth(80) debug
cpm
pip lst:=b:stat.lst
pip lst:=nul:[p]
era b:stat.lst
isdd
link :f1:stat.obj,:f1:x0100,plm80.lib to :f1:stat1.mod
locate :f1:stat1.mod code(0100H) stacksize(100)
era b:stat1.mod
objhex :f1:stat1 to :f1:stat1.hex
link :f1:stat.obj,:f1:x0200,plm80.lib to :f1:stat2.mod
era b:stat.obj
locate :f1:stat2.mod code(0200H) stacksize(100)
era b:stat2.mod
objhex :f1:stat2 to :f1:stat2.hex
era b:stat2
cpm
objcpm b:stat1
era b:stat*.
era b:stat1.com
pip lst:=b:stat1.sym[pt8]
pip lst:=b:stat1.lin[pt8]
pip lst:=nul:[p]
era b:*.lin
era b:*.sym
pip b:stat.hex=b:stat1.hex,b:stat2.hex
era b:stat1.hex
era b:stat2.hex
genmod b:stat.hex b:stat.prl $$1000
era b:*.hex
sub ddtgen
