Upload

Digital Research

ASSEMBLY & COMPILE TOOLS/PLM VAX COMPILER/util86/out11.mar

@@ -0,0 +1,89 @@
+        .TITLE  OUT11.   (UTIL-VAX Library Routines OUTBLANK et al.)
+;-----------------------------------------------------------------------
+;
+;               D I S C L A I M E R   N O T I C E
+;               -------------------   -----------
+;
+;  This document and/or portions of the material and data furnished
+;  herewith, was developed under sponsorship of the U. S. Government.
+;  Neither the U.S. nor the U.S.D.O.E., nor the Leland Stanford Junior
+;  University, nor their employees, nor their respective contractors,
+;  subcontractors, or their employees, makes any warranty, express or
+;  implied, or assumes any liability or responsibility for accuracy,
+;  completeness or usefulness of any information, apparatus, product
+;  or process disclosed, or represents that its use will not infringe
+;  privately-owned rights.  Mention of any product, its manufacturer,
+;  or suppliers shall not, nor is it intended to, imply approval, dis-
+;  approval, or fitness for any particular use.  The U. S. and the
+;  University at all times retain the right to use and disseminate same
+;  for any purpose whatsoever.  Such distribution shall be made by the
+;  National Energy Software Center at the Argonne National Laboratory
+;  and only subject to the distributee furnishing satisfactory proof
+;  that he has a valid license from the Intel Corporation in effect.
+;
+;-----------------------------------------------------------------------
+ 
+        .PSECT  UTIL_CODE,RD,NOWRT,EXE,GBL,CON,LONG
+ 
+;  OUTBLANK: PROCEDURE PUBLIC;
+;  END OUTBLANK;
+ 
+	.ENTRY	OUTBLANK,^M<>
+	MOVB	#^A' ',@OBUFP
+	INCL	OBUFP
+	RET
+ 
+;  OUTCHAR: PROCEDURE (CHAR) PUBLIC;
+;	DECLARE CHAR BYTE;
+;  END OUTCHAR;
+ 
+	.ENTRY	OUTCHAR,^M<>
+	MOVB	4(AP),@OBUFP
+	INCL	OBUFP
+	RET
+ 
+;  OUTCRLF: PROCEDURE PUBLIC;
+;  END OUTCRLF;
+ 
+	.ENTRY	OUTCRLF,^M<>
+	MOVW	#^X0A0D,@OBUFP
+	ADDL2	#2,OBUFP
+	RET
+ 
+;  OUTADDR: PROCEDURE (ADDRV) PUBLIC;
+;	DECLARE ADDRV ADDRESS;
+;  END OUTADDR;
+ 
+	.ENTRY	OUTADDR,^M<>
+	MOVW	4(AP),@OBUFP
+	ADDL2	#2,OBUFP
+	RET
+ 
+;  OUTWRITE: PROCEDURE (PTRX,STRLENGTH) PUBLIC;
+;       DECLARE PTRX ADDRESS, STRLENGTH BYTE;
+;  END OUTWRITE;
+ 
+	.ENTRY	OUTWRITE,^M<R2,R3,R4,R5>
+	MOVC3	8(AP),@4(AP),@OBUFP
+	MOVL	R3,OBUFP		; Update buffer pointer.
+	RET
+ 
+;  OUTPRINT: PROCEDURE (PTRZ) PUBLIC;
+;	DECLARE PTRZ ADDRESS;
+;  END OUTPRINT;
+ 
+	.ENTRY	OUTPRINT,^M<R2,R3,R4,R5>
+        MOVTUC  #255,@4(AP),#0,B^IDENT_MAP,#255,@OBUFP
+	MOVL	R5,OBUFP		; Update buffer pointer.
+	RET
+ 
+;  IDENTITY MAP USED WITH 'MOVTUC' INSTRUCTION IN OUTPRINT.
+ 
+IDENT_MAP:
+	I=0
+	.REPEAT	256
+	.BYTE	I
+	I=I+1
+	.ENDR
+ 
+	.END